\b;Cvičení
Ovládejte na dálku jiného robota bez použití \l;komunikační stanice\u object\exchange;. Robot má za úkol přejet přes 6 modrých křížků. Pro předání povelů dělníkovi musíte použít proměnnou deklarovanou jako \c;static\n;.

Hlavní role v tomto cvičení hrají:
1) \l;Pojízdné rameno\u object\botgr; bez baterie, tím pádem nepojízdné. To je velitel, kterého musíte naprogramovat, aby předával povely dělníkovi.
2) \l;Cvičný robot\u object\bottr;, který už je naprogramovaný a jen čeká na povely od velitele.

\b;Dělník
Nejprve si musíme vysvětlit, jak funguje program dělníka. \l;Třída\u cbot\class; \c;order\n; obsahuje dva atributy: \c;m_type\n; určuje příkaz, který se má provést (\c;move\n; nebo \c;turn\n;) a \c;m_param\n; určuje délku jízdy nebo úhel otočení:

\c;\s;\l;public\u cbot\public; \l;class\u cbot\class; order
\s;{
\s;	\l;int\u cbot\int;    m_type = \l;nan\u cbot\nan;;
\s;	\l;float\u cbot\float;  m_param;
\s;}
\n;
Další \l;třída\u cbot\class; \c;exchange\n; poskytuje mechanismus pro předávání povelů. V ní je deklarovaný \l;statický\u cbot\static; atribut \c;m_order\n;, kam budeme povely ukládat. Klíčové slovo \c;static\n; znamená, že všechny instance \l;třídy\u cbot\class; \c;exchange\n; budou atribut \c;m_order\n; sdílet mezi sebou.

\c;\s;\l;public\u cbot\public; \l;class\u cbot\class; exchange
\s;{
\s;	\l;static\u cbot\static; \l;private\u cbot\private; order m_order = new order;
\n;
\n;Velitel bude pro předání povelu volat metodu \c;put\n;. Pokud atribut \c;m_order\n; neobsahuje hodnotu \c;\l;nan\u cbot\nan;\n;, dělník ještě nedokončil předchozí příkaz, takže metoda \c;put\n; vrátí hodnotu \c;false\n; a nebude nic dělat:

\c;\s;	\l;synchronized\u cbot\synchro; \l;bool\u cbot\bool; put(order a)
\s;	{
\s;		if ( m_order.m_type == nan )
\s;		{
\s;			m_order = a;
\s;			return true;
\s;		}
\s;		else
\s;		{
\s;			return false;
\s;		}
\s;	}
\n;
Dělník si pak povely přečte pomocí metody \c;get\n;. Tato metoda vrátí povel, který se má provést:

\c;\s;	\l;synchronized\u cbot\synchro; order get()
\s;	{
\s;		return m_order;
\s;	}
\n;
Dělník nakonec oznámí splnění povelu metodou \c;delete\n;:

\c;\s;	\l;synchronized\u cbot\synchro; void delete()
\s;	{
\s;		m_order.m_type = nan;
\s;	}
\s;}
\n;
Hlavní program dělníka obsahuje instanci třídy \c;exchange\n; nazvanou \c;list\n;. Závorky za slovem \c;list\n; znamenají, že vytváříme instanci třídy \c;exchange\n;.

\c;\s;\l;extern\u cbot\extern; void object::Slave3( )
\s;{
\s;	exchange list();
\s;	order    todo;
\n;
Vnější cyklus \c;while\n; se opakuje donekonečna. Vnitřní cyklus \c;while\n; čeká na povel a stále volá metodu \c;get\n; třídy \c;exchange\n;. Když metoda \c;get\n; vrátí jinou hodnotu než \c;nan\n;, vnitřní cyklus skončí.

\c;\s;	\l;while\u cbot\while; ( true )
\s;	{
\s;		\l;while\u cbot\while; ( true )
\s;		{
\s;			todo = list.get();
\s;			if ( todo.m_type != nan )  break;
\s;			wait(1);
\s;		}
\n;
Když máme povel uložený v proměnné \c;todo\n;, zbývá ho jen provést:

\c;\s;		if ( todo.m_type == 1 )
\s;		{
\s;			move(todo.m_param);
\s;		}
\s;		else if ( todo.m_type == 2 )
\s;		{
\s;			turn(todo.m_param);
\s;		}
\s;		else
\s;		{
\s;			message("Unknown order");
\s;		}
\n;
Po splnění povelu ještě musíme zavolat metodu \c;delete\n;, aby velitel věděl, že může poslat další povel:

\c;\s;		list.delete();
\s;	}
\s;}
\n;
\b;Velitel
Pro velitele napíšeme funkci \c;SendOrder\n;, která pošle povel dělníkovi:

\c;\s;void object::SendOrder(float order, float param)
\s;{
\s;	exchange list();
\s;	order    todo();
\s;	
\s;	todo.m_type = order;
\s;	todo.m_param = param;
\s;	
\s;	while ( list.put(todo) == false )
\s;	{
\s;		wait(1);
\s;	}
\s;}
\n;
Cyklus \c;while\n; bude čekat na přijetí předchozího povelu, tedy dokud dělník nedokončí volání metody \c;get\n; a následně nezavolá metodu \c;delete\n;.
Dál už bude hlavní program velitele celkem jednoduchý:

\c;\s;extern void object::Ovladac4( )
\s;{
\s;	SendOrder(1, 20);  // move(20);
\s;	SendOrder(2, 90);  // turn(90);
\s;	SendOrder(1, 20);  // move(20);
\s;	SendOrder(2, 90);  // turn(90);
\s;	SendOrder(1, 10);  // move(10);
\s;	SendOrder(2, 90);  // turn(90);
\s;	SendOrder(1, 10);  // move(10);
\s;	SendOrder(2,-90);  // turn(-90);
\s;	SendOrder(1, 10);  // move(10);
\s;}
\n;
Tyto instrukce si můžete kdykoliv znovu přečíst klávesou \key;\key help;\norm;.


\t;Užitečné odkazy
\l;Ovládání\u command; a \l;programování\u cbot;.
