Policy
    name = "PLC_INDUSTRIALISM"
    description = "PLC_INDUSTRIALISM_DESC"
    short_description = "PLC_INDUSTRIALISM_SHORT_DESC"
    category = "ECONOMIC_CATEGORY"
    adoptioncost = floor(2.0 * [[POPULATION_OWNED_BY_EMPIRE]]^0.5)
    exclusions = [ "PLC_ENVIRONMENTALISM" "PLC_MODERATION" "PLC_TECHNOCRACY" ]
    effectsgroups = [
        [[SPECIES_LIKES_OR_DISLIKES_POLICY_STABILITY_EFFECTS]]

        EffectsGroup
            scope = And [
                Planet
                OwnedBy empire = Source.Owner
                Focus type = "FOCUS_INDUSTRY"
                Population low = 0.001
                Happiness low = (NamedReal name = "PLC_INDUSTRIALISM_MIN_STABILITY" value = 5)
            ]
            priority = [[TARGET_2ND_SCALING_PRIORITY]]
            effects =
                SetTargetIndustry value = Value
                    + abs(Value * (NamedReal name = "PLC_INDUSTRIALISM_TARGET_INDUSTRY_PERCENT" value = 25) / 100)

        EffectsGroup
            scope = And [
                Planet
                OwnedBy empire = Source.Owner
                Focus type = "FOCUS_INDUSTRY"
                Population low = 0.001
            ]
            effects =
                SetTargetHappiness value = Value
                    + (NamedReal name = "PLC_INDUSTRIALISM_TARGET_HAPPINESS_FLAT" value = 2)
    ]
    graphic = "icons/policies/economic_industrialism.png"

#include "/scripting/common/priorities.macros"
#include "/scripting/policies/policies.macros"
